CFML makes it simple to instantiate and use native Java classes without leaving CFML-land. For example, we can use Java's SimpleDateFormat library to format a date object:

var dateFormatter = createObject( "java", "java.text.SimpleDateFormat" );
var formattedDate = dateFormatter.init( "yyyy-MM-dd'T'HH:mm: ssXXX" ).format( now() );

In order to use a third-party java library, however, such as the Jsoup HTML parser, you will need to load the jar into the CFML engine first.

There are two main ways to load a Java jar into CFML app:

1. Using native CFML
2. Using Javaloader

Loading Jars with native CFML

Add this to your web root's Application.cfc:

// Java Integration
this.javaSettings = {
   loadPaths               : [ expandPath( "./lib" ) ],
   loadColdFusionClassPath : true,
   reloadOnChange          : false
};

Then add the .jar file to the lib/ directory.

Once this is done, you can use the jar like this:

function getWikipediaPage(){
   var Jsoup = createObject( "java", "org.jsoup.Jsoup" );
   return Jsoup
      .connect( "https://en.wikipedia.org/wiki/The_Lord_of_the_Rings_(film_series)" )
      .get()
      .body()
      .text();
}

Loading Jars with JavaLoader

Javaloader is a CFML tool for loading java .jar files into your CFML application. Javaloader offers an improved developer experience, as there is no need to adjust application settings or restart the server after installation. With Javaloader, you can ship your dependencies with a module or library, and it "just works" without requiring further configuration.

box install cbjavaloader

Once javaloader installs, you can inject the Jsoup library into your components using the custom Javaloader syntax for Wirebox:

component{
    property name="Jsoup" inject="javaloader:org.jsoup.Jsoup";
    // ...
}

Once we’ve injected Jsoup, we can use Jsoup to fetch and parse the Wikipedia page for the LOTR film series:

function getWikipediaPage(){
   return Jsoup
      .connect( "https://en.wikipedia.org/wiki/The_Lord_of_the_Rings_(film_series)" )
      .get()
      .body()
      .text();
}

And that's how you use the Java "Jsoup" library in CFML!